@echo off
title AZA / MedWork Starter (RESET)
setlocal EnableExtensions DisableDelayedExpansion

cd /d "%~dp0"

set "PYTHON=C:\Users\surov\AppData\Local\Programs\Python\Python312\python.exe"
set "AZA_TLS_REQUIRE=0"

set "PORT=8001"
set "MEDWORK_BACKEND_URL=http://127.0.0.1:%PORT%"

REM Variante-B-Schutz: backend_url.txt nicht ueberschreiben wenn Live-Backend konfiguriert
if not exist "%~dp0backend_url.txt" goto write_local_url
findstr /i "api.aza-medwork" "%~dp0backend_url.txt" >nul 2>&1
if not errorlevel 1 (
  echo HINWEIS: backend_url.txt zeigt auf Live-Backend, wird NICHT ueberschrieben.
  echo   Fuer lokalen Dev-Modus: manuell auf http://127.0.0.1:%PORT% aendern.
  goto skip_url_write
)
:write_local_url
>"%~dp0backend_url.txt" echo %MEDWORK_BACKEND_URL%
:skip_url_write

REM Token aus Datei lesen und als ENV setzen (ohne Echo des Tokens)
set /p MEDWORK_API_TOKEN=<"%~dp0backend_token.txt"

echo.
echo ==========================================
echo   RESET START
echo ==========================================
echo Folder: %~dp0
echo Python: %PYTHON%
echo URL:    %MEDWORK_BACKEND_URL%
echo TLS:    %AZA_TLS_REQUIRE%
echo Token:  (gesetzt)
echo.

echo Starte Backend...
start "MedWork Backend" /D "%~dp0" "%PYTHON%" -u backend_main.py

timeout /t 2 >nul

echo Starte Client...
start "MedWork Client" /D "%~dp0" "%PYTHON%" -u basis14.py

echo.
echo Fertig. (Falls nichts sichtbar ist: Alt+Tab)
echo.
endlocal